gcc-sanitizers: Enable GCC sanitizers
AddressSanitizer is a fast memory error detector. ThreadSanitizer detects data races. UBSanitizer detectes undefined behaviour. All consist of compiler instrumentation and a run-time library. The compiler instrumentation was already enabled, this builds the run-time library component. (From OE-Core rev: 1709bf0c3a84bb04bc52e9104ad8e09fba6c6f91) Signed-off-by: Dan McGregor <dan.mcgregor@usask.ca> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
This commit is contained in:
parent
5b985fd364
commit
166015c809
|
@ -29,6 +29,7 @@ SECURITY_CFLAGS_pn-glibc-initial = ""
|
|||
SECURITY_CFLAGS_pn-enchant = "${SECURITY_NO_PIE_CFLAGS}"
|
||||
SECURITY_CFLAGS_pn-flac = "${SECURITY_NO_PIE_CFLAGS}"
|
||||
SECURITY_CFLAGS_pn-gcc-runtime = "${SECURITY_NO_PIE_CFLAGS}"
|
||||
SECURITY_CFLAGS_pn-gcc-sanitizers = "${SECURITY_NO_PIE_CFLAGS}"
|
||||
SECURITY_CFLAGS_pn-gdb = "${SECURITY_NO_PIE_CFLAGS}"
|
||||
SECURITY_CFLAGS_pn-gmp = "${SECURITY_NO_PIE_CFLAGS}"
|
||||
SECURITY_CFLAGS_pn-gnutls = "${SECURITY_NO_PIE_CFLAGS}"
|
||||
|
|
|
@ -36,8 +36,10 @@ PREFERRED_VERSION_gcc-crosssdk-${SDK_ARCH} ?= "${SDKGCCVERSION}"
|
|||
PREFERRED_VERSION_gcc-crosssdk-initial-${SDK_ARCH} ?= "${SDKGCCVERSION}"
|
||||
PREFERRED_VERSION_gcc-cross-canadian-${TRANSLATED_TARGET_ARCH} ?= "${GCCVERSION}"
|
||||
PREFERRED_VERSION_gcc-runtime ?= "${GCCVERSION}"
|
||||
PREFERRED_VERSION_gcc-sanitizers ?= "${GCCVERSION}"
|
||||
PREFERRED_VERSION_gcc-source ?= "${GCCVERSION}"
|
||||
PREFERRED_VERSION_nativesdk-gcc-runtime ?= "${SDKGCCVERSION}"
|
||||
PREFERRED_VERSION_nativesdk-gcc-sanitizers ?= "${GCCVERSION}"
|
||||
PREFERRED_VERSION_libgcc ?= "${GCCVERSION}"
|
||||
PREFERRED_VERSION_libgcc-initial ?= "${GCCVERSION}"
|
||||
PREFERRED_VERSION_nativesdk-libgcc ?= "${SDKGCCVERSION}"
|
||||
|
|
|
@ -0,0 +1,111 @@
|
|||
require gcc-configure-common.inc
|
||||
|
||||
EXTRA_OECONF_PATHS = "\
|
||||
--with-sysroot=/not/exist \
|
||||
--with-build-sysroot=${STAGING_DIR_TARGET} \
|
||||
"
|
||||
|
||||
do_configure () {
|
||||
mtarget=`echo ${TARGET_SYS} | sed -e s#-${SDKPKGSUFFIX}##`
|
||||
target=`echo ${TARGET_SYS} | sed -e s#-${SDKPKGSUFFIX}##`
|
||||
hardlinkdir ${STAGING_INCDIR_NATIVE}/gcc-build-internal-$mtarget ${B}
|
||||
|
||||
echo "Configuring libsanitizer"
|
||||
rm -rf ${B}/$target/libsanitizer/
|
||||
mkdir -p ${B}/$target/libsanitizer/
|
||||
# This is kind of gross, but it's an easy way to make configure happy
|
||||
# without hacking it up to use the system stdc++ instead of the one it
|
||||
# expects to be newly built.
|
||||
rm -rf ${B}/$target/libstdc++-v3/
|
||||
mkdir -p ${B}/$target/libstdc++-v3/src/
|
||||
ln -s ${STAGING_LIBDIR}/libstdc++.la ${B}/$target/libstdc++-v3/src/
|
||||
ln -s ${STAGING_LIBDIR}/libstdc++.so ${B}/$target/libstdc++-v3/src/
|
||||
cd ${B}/$target/libsanitizer/
|
||||
chmod a+x ${S}/libsanitizer/configure
|
||||
${S}/libsanitizer/configure ${CONFIGUREOPTS} ${EXTRA_OECONF}
|
||||
# Easiest way to stop bad RPATHs getting into the library since we have a
|
||||
# broken libtool here
|
||||
sed -i -e 's/hardcode_into_libs=yes/hardcode_into_libs=no/' ${B}/$target/libsanitizer/libtool
|
||||
}
|
||||
|
||||
do_compile () {
|
||||
target=`echo ${TARGET_SYS} | sed -e s#-${SDKPKGSUFFIX}##`
|
||||
cd ${B}/$target/libsanitizer/
|
||||
oe_runmake MULTIBUILDTOP=${B}/$target/libsanitizer/
|
||||
}
|
||||
|
||||
do_install () {
|
||||
target=`echo ${TARGET_SYS} | sed -e s#-${SDKPKGSUFFIX}##`
|
||||
cd ${B}/$target/libsanitizer/
|
||||
oe_runmake 'DESTDIR=${D}' MULTIBUILDTOP=${B}/$target/libsanitizer/ install
|
||||
if [ -d ${D}${infodir} ]; then
|
||||
rmdir --ignore-fail-on-non-empty -p ${D}${infodir}
|
||||
fi
|
||||
chown -R root:root ${D}
|
||||
}
|
||||
|
||||
INHIBIT_DEFAULT_DEPS = "1"
|
||||
ALLOW_EMPTY_${PN} = "1"
|
||||
DEPENDS = "gcc-runtime"
|
||||
|
||||
BBCLASSEXTEND = "nativesdk"
|
||||
|
||||
PACKAGES = "${PN}"
|
||||
PACKAGES += "libasan libubsan liblsan libtsan"
|
||||
PACKAGES += "libasan-dev libubsan-dev liblsan-dev libtsan-dev"
|
||||
PACKAGES += "libasan-dbg libubsan-dbg liblsan-dbg libtsan-dbg"
|
||||
PACKAGES += "libasan-staticdev libubsan-staticdev liblsan-staticdev libtsan-staticdev"
|
||||
|
||||
RDEPENDS_libasan += "libstdc++"
|
||||
RDEPENDS_libubsan += "libstdc++"
|
||||
RDEPENDS_liblsan += "libstdc++"
|
||||
RDEPENDS_libtsan += "libstdc++"
|
||||
RDEPENDS_libasan-dev += "${PN}"
|
||||
RDEPENDS_libubsan-dev += "${PN}"
|
||||
RDEPENDS_liblsan-dev += "${PN}"
|
||||
RDEPENDS_libtsan-dev += "${PN}"
|
||||
RRECOMMENDS_${PN} += "libasan libubsan"
|
||||
RRECOMMENDS_${PN}_append_x86-64 = " liblsan libtsan"
|
||||
RRECOMMENDS_${PN}_append_x86 = " liblsan"
|
||||
|
||||
do_package_write_ipk[depends] += "virtual/${MLPREFIX}${TARGET_PREFIX}compilerlibs:do_packagedata"
|
||||
do_package_write_deb[depends] += "virtual/${MLPREFIX}${TARGET_PREFIX}compilerlibs:do_packagedata"
|
||||
do_package_write_rpm[depends] += "virtual/${MLPREFIX}${TARGET_PREFIX}compilerlibs:do_packagedata"
|
||||
|
||||
# MIPS, aarch64, and SPARC are broken.
|
||||
COMPATIBLE_HOST = '(x86_64|i.86|powerpc|arm).*-linux'
|
||||
|
||||
FILES_libasan += "${libdir}/libasan.so.*"
|
||||
FILES_libasan-dbg += "${libdir}/.debug/libasan.so.*"
|
||||
FILES_libasan-dev += "\
|
||||
${libdir}/libasan_preinit.o \
|
||||
${libdir}/libasan.so \
|
||||
${libdir}/libasan.la \
|
||||
"
|
||||
FILES_libasan-staticdev += "${libdir}/libasan.a"
|
||||
|
||||
FILES_libubsan += "${libdir}/libubsan.so.*"
|
||||
FILES_libubsan-dbg += "${libdir}/.debug/libubsan.so.*"
|
||||
FILES_libubsan-dev += "\
|
||||
${libdir}/libubsan.so \
|
||||
${libdir}/libubsan.la \
|
||||
"
|
||||
FILES_libubsan-staticdev += "${libdir}/libubsan.a"
|
||||
|
||||
FILES_liblsan += "${libdir}/liblsan.so.*"
|
||||
FILES_liblsan-dbg += "${libdir}/.debug/liblsan.so.*"
|
||||
FILES_liblsan-dev += "\
|
||||
${libdir}/liblsan.so \
|
||||
${libdir}/liblsan.la \
|
||||
"
|
||||
FILES_liblsan-staticdev += "${libdir}/liblsan.a"
|
||||
|
||||
FILES_libtsan += "${libdir}/libtsan.so.*"
|
||||
FILES_libtsan-dbg += "${libdir}/.debug/libtsan.so.*"
|
||||
FILES_libtsan-dev += "\
|
||||
${libdir}/libtsan.so \
|
||||
${libdir}/libtsan.la \
|
||||
"
|
||||
FILES_libtsan-staticdev += "${libdir}/libtsan.a"
|
||||
|
||||
FILES_${PN} = "${libdir}/*.spec ${libdir}/gcc/${TARGET_SYS}/${BINV}/include/sanitizer/*.h"
|
|
@ -0,0 +1,2 @@
|
|||
require recipes-devtools/gcc/gcc-${PV}.inc
|
||||
require gcc-sanitizers.inc
|
|
@ -0,0 +1,2 @@
|
|||
require recipes-devtools/gcc/gcc-${PV}.inc
|
||||
require gcc-sanitizers.inc
|
Loading…
Reference in New Issue