prserv: add LOCALCOUNT to AUTOINCs migration feature

- use migrate_localcount.bbclass to generate AUTOINC entries
which are exported to LOCALCOUNT_DUMPFILE
- import the generated AUTOINC entries
- one can migrate LOCALCOUNT to AUTOINC by executing:
    bitbake-prserv-tool migrate_localcount

[YOCTO #3071]

(From OE-Core rev: ffab86f13cafb10d8d6273b6af8cd9a3c84eae20)

Signed-off-by: Constantin Musca <constantinx.musca@intel.com>
Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>

meta/classes/migrate_localcount.bbclass

@@ -0,0 +1,47 @@
+PRSERV_DUMPDIR ??= "${LOG_DIR}/db"
+LOCALCOUNT_DUMPFILE ??= "${PRSERV_DUMPDIR}/prserv-localcount-exports.inc"
+
+python migrate_localcount_handler () {
+    import bb.event
+    if not e.data:
+        return
+
+    if isinstance(e, bb.event.RecipeParsed):
+        pv = e.data.getVar('PV', True)
+        if not 'AUTOINC' in pv:
+            return
+
+        localcounts = bb.persist_data.persist('BB_URI_LOCALCOUNT', e.data)
+        pn = e.data.getVar('PN', True)
+        revs = localcounts.get_by_pattern('%%-%s_rev' % pn)
+        counts = localcounts.get_by_pattern('%%-%s_count' % pn)
+        if not revs or not counts:
+            return
+
+        srcrev = bb.fetch2.get_srcrev(e.data)
+        bpv = pv[:pv.find(srcrev)]
+
+        if len(revs) != len(counts):
+            bb.warn("The number of revs and localcounts don't match in %s" % pn)
+            return
+
+        version = 'AUTOINC-%s-%s' % (pn, bpv)
+        pkgarch = e.data.getVar('PACKAGE_ARCH', True)
+        value = max(int(count) for count in counts)
+
+        if len(revs) == 1:
+            if srcrev != ('AUTOINC+%s' % revs[0]):
+                value += 1
+        else:
+            value += 1
+
+        bb.utils.mkdirhier(e.data.getVar('PRSERV_DUMPDIR', True))
+        df = e.data.getVar('LOCALCOUNT_DUMPFILE', True)
+        flock = bb.utils.lockfile("%s.lock" % df)
+        with open(df, 'a') as fd:
+            fd.write('PRAUTO$%s$%s$%s = "%s"\n' %
+                    (version, pkgarch, srcrev, str(value)))
+        bb.utils.unlockfile(flock)
+}
+
+addhandler migrate_localcount_handler

meta/conf/migrate_localcount.conf

@@ -0,0 +1 @@
+INHERIT += "migrate_localcount"

scripts/bitbake-prserv-tool

@@ -47,6 +47,35 @@ do_import ()
     return $ret
 }
 
+do_migrate_localcount ()
+{
+    df=`bitbake -R conf/migrate_localcount.conf -e | \
+                grep ^LOCALCOUNT_DUMPFILE= | cut -f2 -d\"`
+    if [ "x${df}" == "x" ];
+    then
+        echo "LOCALCOUNT_DUMPFILE is not defined!"
+        return 1
+    fi
+
+    rm -rf $df
+    clean_cache
+    echo "Exporting LOCALCOUNT to AUTOINCs..."
+    bitbake -R conf/migrate_localcount.conf -p
+    [ ! $? -eq 0 ] && echo "Exporting failed!" && exit 1
+
+    echo "Importing generated AUTOINC entries..."
+    [ -e $df ] && do_import $df
+
+    if [ ! $? -eq 0 ]
+    then
+        echo "Migration from LOCALCOUNT to AUTOINCs failed!"
+        return 1
+    fi
+
+    echo "Migration from LOCALCOUNT to AUTOINCs succeeded!"
+    return 0
+}
+
 [ $# -eq 0 ] && help  && exit 1
 
 case $1 in
@@ -56,6 +85,9 @@ export)
 import)
     do_import $2
     ;;
+migrate_localcount)
+    do_migrate_localcount
+    ;;
 *)
     help
     exit 1