Add HAL from git, faster and uses less memory

git-svn-id: https://svn.o-hand.com/repos/poky/trunk@1179 311d38ba-8fff-0310-9ca6-ca027cbcb966
2007-01-20 14:19:55 +00:00 · 2007-01-20 14:19:55 +00:00 · ecf5c09762
parent 38ae29b091
commit ecf5c09762
1 changed files with 82 additions and 0 deletions
--- a/meta/packages/hal/hal_git.bb
+++ b/meta/packages/hal/hal_git.bb
@ -0,0 +1,82 @@
+DESCRIPTION = "Hardware Abstraction Layer"
+HOMEPAGE = "http://freedesktop.org/Software/hal"
+SECTION = "unknown"
+LICENSE = "GPL LGPL AFL"
+
+DEPENDS = "dbus-glib  expat libusb"
+RDEPENDS += "udev"
+#RDEPENDS_hal-device-manager = "python hal python-pygnome"
+RRECOMMENDS = "udev-utils"
+
+SRC_URI = "git://anongit.freedesktop.org/hal/;protocol=git \
+        file://99_hal"
+
+S = "${WORKDIR}/git"
+
+inherit autotools pkgconfig
+
+EXTRA_OECONF = "--with-hwdata=${datadir}/hwdata \
+                --with-expat=${STAGING_LIBDIR}/.. \
+                --with-dbus-sys=${sysconfdir}/dbus-1/system.d \
+                --with-hotplug=${sysconfdir}/hotplug.d \
+                --disable-docbook-docs \
+                --disable-policy-kit \
+                --disable-acpi --disable-pmu \
+                "
+
+do_install_append() {
+	install -d ${D}/etc/default/volatiles
+	install -m 0644 ${WORKDIR}/99_hal ${D}/etc/default/volatiles
+}
+
+do_stage() {
+        autotools_stage_all
+        install -d ${STAGING_LIBDIR}
+        install -m 755 libhal/.libs/libhal.so.1.0.0 ${STAGING_LIBDIR}/libhal.so
+        install -m 755 libhal-storage/.libs/libhal-storage.so.1.0.0 ${STAGING_LIBDIR}/libhal-storage.so
+}
+
+# At the time the postinst runs, dbus might not be setup so only restart if running
+pkg_postinst_hal () {
+	# can't do this offline
+	if [ "x$D" != "x" ]; then
+		exit 1
+	fi
+
+	/etc/init.d/populate-volatile.sh update
+
+	grep haldaemon /etc/group || addgroup haldaemon
+	grep haldaemon /etc/passwd || adduser --disabled-password --system --home /var/run/hald --no-create-home haldaemon --ingroup haldaemon -g HAL
+
+	DBUSPID=`pidof dbus-daemon`
+
+	if [ "x$DBUSPID" != "x" ]; then
+		/etc/init.d/dbus-1 force-reload
+	fi
+}
+
+pkg_postrm_hal () {
+	deluser haldaemon || true
+	delgroup haldaemon || true
+}
+
+#PACKAGES += "hal-device-manager"
+
+#FILES_hal-device-manager = " \
+#               ${datadir}/hal/device-manager/ \
+#               ${bindir}/hal-device-manager"
+
+FILES_${PN} = "${sysconfdir} \
+                ${bindir}/lshal \
+                ${bindir}/hal-find-by-capability \
+                ${bindir}/hal-find-by-property \
+                ${bindir}/hal-device  \
+                ${bindir}/hal-get-property \
+                ${bindir}/hal-set-property  \
+                ${sbindir} \
+                ${libdir}/libhal.so* \
+                ${libdir}/libhal-storage.so* \
+                ${libdir}/hal \
+                ${libexecdir} \
+                ${datadir}/hal/fdi \
+                ${datadir}/hal/scripts"