ff0a6211cd
git-svn-id: https://svn.o-hand.com/repos/poky/trunk@2593 311d38ba-8fff-0310-9ca6-ca027cbcb966
106 lines
3.7 KiB
PHP
106 lines
3.7 KiB
PHP
DESCRIPTION = "2.6 Linux Development Kernel for FIC Neo1973 (GTA01)"
|
|
SECTION = "kernel"
|
|
AUTHOR = "Harald Welte <laforge@openmoko.org>"
|
|
HOMEPAGE = "N/A"
|
|
LICENSE = "GPL"
|
|
DEPENDS += "u-boot-mkimage-gta01-native"
|
|
|
|
inherit kernel
|
|
|
|
FILESDIR = "${@os.path.dirname(bb.data.getVar('FILE',d,1))}/linux-gta01"
|
|
|
|
##############################################################
|
|
# source and patches
|
|
#
|
|
SRC_URI = "${KERNELORG_MIRROR}/pub/linux/kernel/v2.6/linux-${VANILLA_VERSION}.tar.bz2 \
|
|
file://defconfig-${VANILLA_VERSION}-${MACHINE} \
|
|
file://logo_linux_clut224.ppm"
|
|
S = "${WORKDIR}/linux-${VANILLA_VERSION}"
|
|
|
|
##############################################################
|
|
# kernel image resides on a seperate flash partition (for now)
|
|
#
|
|
FILES_kernel-image = ""
|
|
ALLOW_EMPTY = "1"
|
|
|
|
COMPATIBLE_MACHINE = 'fic-gta01'
|
|
|
|
CMDLINE_CON = ""
|
|
#CMDLINE_ROOT = "root=/dev/mmcblk0p1 rootfstype=ext3 rootdelay=5"
|
|
# uncomment if you want to boot over NFS
|
|
#CMDLINE_ROOT = "root=/dev/nfs nfsroot=192.168.1.10:/export/opie-image rootdelay=5 3"
|
|
# uncomment to enable dyntick
|
|
#CMDLINE_OTHER = "dyntick=enable"
|
|
CMDLINE_DEBUG = '${@base_conditional("DISTRO_TYPE", "release", "quiet", "debug",d)}'
|
|
CMDLINE_IP = "ip=192.168.1.2:192.168.1.10:192.168.1.10:255.255.255.0:ezx:usb0:off"
|
|
CMDLINE = "${CMDLINE_CON} ${CMDLINE_ROOT} ${CMDLINE_IP} ${CMDLINE_ROTATE} ${CMDLINE_OTHER} ${CMDLINE_DEBUG}"
|
|
|
|
###############################################################
|
|
# module configs specific to this kernel
|
|
#
|
|
|
|
# usb
|
|
module_autoload_ohci-hcd = "ohci-hcd"
|
|
module_autoload_hci_usb = "hci_usb"
|
|
module_autoload_g_ether = "g_ether"
|
|
# audio
|
|
module_autoload_snd-soc-neo1973-wm8753 = "snd-soc-neo1973-wm8753"
|
|
# sd/mmc
|
|
module_autoload_s3cmci = "s3cmci"
|
|
|
|
do_prepatch() {
|
|
mv ${WORKDIR}/patches ${S}/patches && cd ${S} && quilt push -av
|
|
mv patches patches.openmoko
|
|
mv .pc .pc.old
|
|
}
|
|
|
|
do_configure() {
|
|
install -m 0644 ${WORKDIR}/logo_linux_clut224.ppm drivers/video/logo/logo_linux_clut224.ppm
|
|
|
|
if [ ! -e ${WORKDIR}/defconfig-${VANILLA_VERSION}-${MACHINE} ]; then
|
|
die "No default configuration for ${MACHINE} available."
|
|
fi
|
|
|
|
echo "CONFIG_CMDLINE=\"${CMDLINE}\"" >> ${S}/.config
|
|
|
|
if [ "${TARGET_OS}" = "linux-gnueabi" ]; then
|
|
echo "CONFIG_AEABI=y" >> ${S}/.config
|
|
echo "CONFIG_OABI_COMPAT=y" >> ${S}/.config
|
|
else
|
|
echo "# CONFIG_AEABI is not set" >> ${S}/.config
|
|
echo "# CONFIG_OABI_COMPAT is not set" >> ${S}/.config
|
|
fi
|
|
|
|
sed -e '/CONFIG_AEABI/d' \
|
|
-e '/CONFIG_OABI_COMPAT=/d' \
|
|
-e '/CONFIG_CMDLINE=/d' \
|
|
-e '/CONFIG_MTD_MTDRAM_SA1100=/d' \
|
|
-e '/CONFIG_MTDRAM_TOTAL_SIZE=/d' \
|
|
-e '/CONFIG_MTDRAM_ERASE_SIZE=/d' \
|
|
-e '/CONFIG_MTDRAM_ABS_POS=/d' \
|
|
'${WORKDIR}/defconfig-${VANILLA_VERSION}-${MACHINE}' >>'${S}/.config'
|
|
|
|
yes '' | oe_runmake oldconfig
|
|
}
|
|
|
|
###############################################################
|
|
# put into deploy directory and append u-boot header
|
|
#
|
|
do_deploy() {
|
|
install -d ${DEPLOY_DIR_IMAGE}
|
|
install -m 0644 arch/${ARCH}/boot/${KERNEL_IMAGETYPE} ${DEPLOY_DIR_IMAGE}/${KERNEL_IMAGETYPE}-${PV}-${PR}-${MACHINE}-${DATETIME}.bin
|
|
tar -cvzf ${DEPLOY_DIR_IMAGE}/modules-${KERNEL_RELEASE}-${PR}-${MACHINE}.tgz -C ${D} lib
|
|
${OBJCOPY} -O binary -R .note -R .comment -S vmlinux linux.bin
|
|
rm -f linux.bin.gz
|
|
gzip -9 linux.bin
|
|
${STAGING_BINDIR_NATIVE}/uboot-mkimage -A arm -O linux -T kernel -C gzip -a 30008000 -e 30008000 -n "OpenMoko Kernel Image Neo1973(GTA01)" -d linux.bin.gz ${DEPLOY_DIR_IMAGE}/uImage-${PV}-${PR}-${MACHINE}.bin
|
|
ln -sf ${DEPLOY_DIR_IMAGE}/uImage-${PV}-${PR}-${MACHINE}.bin ${DEPLOY_DIR_IMAGE}/uImage-${MACHINE}-latest.bin
|
|
rm -f linux.bin.gz
|
|
}
|
|
|
|
do_deploy[dirs] = "${S}"
|
|
|
|
addtask prepatch before do_patch after do_unpack
|
|
addtask deploy before do_package after do_install
|
|
|