69e836604f
'at' needs flex to generate source file lex.yy.c, but it doesn't depend on flex-native directly; This maybe cause a do_compile failure if flex-native is not built or included in project. Error message is: error: lex.yy.c: No such file or directory Get 'at' depends on flex-native to fix this potential issue. [YOCTO #2919] (From OE-Core rev: f5a722a1db6315ba945c41551c60b1ef2c8b647f) Signed-off-by: Wenzong Fan <wenzong.fan@windriver.com> Signed-off-by: Saul Wold <sgw@linux.intel.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
62 lines
2 KiB
BlitzBasic
62 lines
2 KiB
BlitzBasic
SUMMARY = "Delayed job execution and batch processing"
|
|
DESCRIPTION = "At allows for commands to be run at a particular time. Batch will execute commands when \
|
|
the system load levels drop to a particular level."
|
|
SECTION = "base"
|
|
LICENSE="GPLv2+"
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=4325afd396febcb659c36b49533135d4"
|
|
DEPENDS = "flex flex-native initscripts \
|
|
${@base_contains('DISTRO_FEATURES', 'pam', 'libpam', '', d)}"
|
|
RDEPENDS_${PN} = "${@base_contains('DISTRO_FEATURES', 'pam', '${PAM_DEPS}', '', d)}"
|
|
PAM_DEPS = "libpam libpam-runtime pam-plugin-env pam-plugin-limits"
|
|
|
|
RCONFLICTS_${PN} = "atd"
|
|
RREPLACES_${PN} = "atd"
|
|
PR = "r3"
|
|
|
|
SRC_URI = "${DEBIAN_MIRROR}/main/a/at/at_${PV}.orig.tar.gz \
|
|
file://configure.patch \
|
|
file://use-ldflags.patch \
|
|
file://fix_parallel_build_error.patch \
|
|
file://posixtm.c \
|
|
file://posixtm.h \
|
|
file://file_replacement_with_gplv2.patch \
|
|
file://S99at \
|
|
${@base_contains('DISTRO_FEATURES', 'pam', '${PAM_SRC_URI}', '', d)}"
|
|
|
|
PAM_SRC_URI = "file://pam.conf.patch \
|
|
file://configure-add-enable-pam.patch"
|
|
|
|
SRC_URI[md5sum] = "1da61af6c29e323abaaf13ee1a8dad79"
|
|
SRC_URI[sha256sum] = "3a8b90868d615d21a92f4986ea9a823886329af8fae8dd7ab4eed9b273bca072"
|
|
|
|
EXTRA_OECONF += "ac_cv_path_SENDMAIL=/bin/true \
|
|
--with-daemon_username=root \
|
|
--with-daemon_groupname=root \
|
|
--with-jobdir=/var/spool/at/jobs \
|
|
--with-atspool=/var/spool/at/spool \
|
|
${@base_contains('DISTRO_FEATURES', 'pam', '--with-pam', '--without-pam', d)} "
|
|
|
|
inherit autotools
|
|
|
|
PARALLEL_MAKE = ""
|
|
|
|
do_compile_prepend () {
|
|
cp -f ${WORKDIR}/posixtm.[ch] ${S}
|
|
}
|
|
|
|
do_install () {
|
|
oe_runmake -e "IROOT=${D}" install
|
|
|
|
install -d ${D}${sysconfdir}/init.d
|
|
install -d ${D}${sysconfdir}/rcS.d
|
|
install -m 0755 ${WORKDIR}/S99at ${D}${sysconfdir}/init.d/atd
|
|
ln -sf ../init.d/atd ${D}${sysconfdir}/rcS.d/S99at
|
|
|
|
for feature in ${DISTRO_FEATURES}; do
|
|
if [ "$feature" = "pam" ]; then
|
|
install -D -m 0644 ${WORKDIR}/${BP}/pam.conf ${D}${sysconfdir}/pam.d/atd
|
|
break
|
|
fi
|
|
done
|
|
}
|