Multiple integer overflows in GNU Grep before 2.11 might allow context-dependent attackers to execute arbitrary code via vectors involving a long input line that triggers a heap-based buffer overflow. http://web.nvd.nist.gov/view/vuln/detail?vulnId=CVE-2012-5667 (From OE-Core rev: 7dd4d0178e2b057f76cd2b0b6fe8402f8c1ab23d) Signed-off-by: Ming Liu <ming.liu@windriver.com> Signed-off-by: Mark Hatle <mark.hatle@windriver.com> Signed-off-by: Saul Wold <sgw@linux.intel.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
49 lines
1.5 KiB
BlitzBasic
49 lines
1.5 KiB
BlitzBasic
SUMMARY = "Pattern matching utilities"
|
|
DESCRIPTION = "The GNU versions of commonly used grep utilities. The grep command searches one or more input \
|
|
files for lines containing a match to a specified pattern."
|
|
SECTION = "console/utils"
|
|
LICENSE = "GPLv2"
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=0636e73ff0215e8d672dc4c32c317bb3"
|
|
|
|
PR = "r2"
|
|
|
|
SRC_URI = "${GNU_MIRROR}/grep/grep-${PV}.tar.bz2 \
|
|
file://uclibc-fix.patch \
|
|
file://grep_fix_for_automake-1.12.patch \
|
|
file://gettext.patch \
|
|
file://fix64-int-to-pointer.patch \
|
|
file://Makevars \
|
|
file://grep-CVE-2012-5667.patch \
|
|
"
|
|
|
|
SRC_URI[md5sum] = "52202fe462770fa6be1bb667bd6cf30c"
|
|
SRC_URI[sha256sum] = "38c8a2bb9223d1fb1b10bdd607cf44830afc92fd451ac4cd07619bf92bdd3132"
|
|
|
|
inherit autotools gettext
|
|
|
|
EXTRA_OECONF = "--disable-perl-regexp --disable-ncurses"
|
|
|
|
CFLAGS += "-D PROTOTYPES"
|
|
do_configure_prepend () {
|
|
rm -f ${S}/m4/init.m4
|
|
cp -f ${WORKDIR}/Makevars ${S}/po/
|
|
}
|
|
|
|
do_install () {
|
|
autotools_do_install
|
|
install -d ${D}${base_bindir}
|
|
mv ${D}${bindir}/grep ${D}${base_bindir}/grep
|
|
mv ${D}${bindir}/egrep ${D}${base_bindir}/egrep
|
|
mv ${D}${bindir}/fgrep ${D}${base_bindir}/fgrep
|
|
rmdir ${D}${bindir}/
|
|
}
|
|
|
|
inherit update-alternatives
|
|
|
|
ALTERNATIVE_PRIORITY = "100"
|
|
|
|
ALTERNATIVE_${PN} = "grep egrep fgrep"
|
|
ALTERNATIVE_LINK_NAME[grep] = "${base_bindir}/grep"
|
|
ALTERNATIVE_LINK_NAME[egrep] = "${base_bindir}/egrep"
|
|
ALTERNATIVE_LINK_NAME[fgrep] = "${base_bindir}/fgrep"
|