2752d71e8d
The shebang's length is usually 128 as defined in /usr/include/linux/binfmts.h: #define BINPRM_BUF_SIZE 128 So there would be errors when /path/to/hosttools/bash is longer than 128: /bin/sh: ./doltcompile: [snip]: bad interpreter: No such file or directory Set ac_cv_path_DOLT_BASH to "/usr/bin/env bash" to fix the problem. (From OE-Core rev: fd2758ed26e8ed6d76c66af0275c4aafbec758ac) Signed-off-by: Robert Yang <liezhi.yang@windriver.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
46 lines
1.6 KiB
PHP
46 lines
1.6 KiB
PHP
# Copyright (C) 2012 Khem Raj <raj.khem@gmail.com>
|
|
# Released under the MIT license (see COPYING.MIT for the terms)
|
|
|
|
SUMMARY = "Tools for managing Linux kernel modules"
|
|
DESCRIPTION = "kmod is a set of tools to handle common tasks with Linux kernel modules like \
|
|
insert, remove, list, check properties, resolve dependencies and aliases."
|
|
HOMEPAGE = "http://packages.profusion.mobi/kmod/"
|
|
LICENSE = "GPL-2.0+ & LGPL-2.1+"
|
|
LICENSE_libkmod = "LGPL-2.1+"
|
|
SECTION = "base"
|
|
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=a6f89e2100d9b6cdffcea4f398e37343 \
|
|
file://libkmod/COPYING;md5=a6f89e2100d9b6cdffcea4f398e37343 \
|
|
"
|
|
inherit autotools gtk-doc pkgconfig manpages
|
|
|
|
SRCREV = "65a885df5f6f15222b44fd695c5eaca17e837a14"
|
|
# Lookout for PV bump too when SRCREV is changed
|
|
PV = "23+git${SRCPV}"
|
|
|
|
SRC_URI = "git://git.kernel.org/pub/scm/utils/kernel/kmod/kmod.git \
|
|
file://depmod-search.conf \
|
|
file://avoid_parallel_tests.patch \
|
|
file://fix-O_CLOEXEC.patch \
|
|
file://kcmdline_quotes.patch \
|
|
"
|
|
|
|
S = "${WORKDIR}/git"
|
|
|
|
EXTRA_AUTORECONF += "--install --symlink"
|
|
EXTRA_OECONF +=" --enable-tools --with-zlib"
|
|
|
|
CACHED_CONFIGUREVARS += "ac_cv_path_DOLT_BASH='/usr/bin/env bash'"
|
|
|
|
PACKAGECONFIG[debug] = "--enable-debug,--disable-debug"
|
|
PACKAGECONFIG[logging] = " --enable-logging,--disable-logging"
|
|
PACKAGECONFIG[manpages] = "--enable-manpages, --disable-manpages, libxslt-native xmlto-native"
|
|
|
|
do_configure_prepend () {
|
|
gtkdocize --docdir ${S}/libkmod/docs --srcdir ${S}
|
|
}
|
|
|
|
do_configure_append () {
|
|
sed -i 's#}libtool#}${TARGET_SYS}-libtool#' ${B}/doltlibtool
|
|
}
|