63 lines
2.2 KiB
BlitzBasic
63 lines
2.2 KiB
BlitzBasic
DESCRIPTION = "A multi-purpose linux bootloader"
|
|
HOMEPAGE = "http://syslinux.zytor.com/"
|
|
LICENSE = "GPLv2+"
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=0636e73ff0215e8d672dc4c32c317bb3 \
|
|
file://README;beginline=35;endline=41;md5=f7249a750bc692d1048b2626752aa415"
|
|
|
|
# If you really want to run syslinux, you need mtools. We just want the
|
|
# ldlinux.* stuff for now, so skip mtools-native
|
|
DEPENDS = "nasm-native util-linux"
|
|
PR = "r0"
|
|
|
|
SRC_URI = "${KERNELORG_MIRROR}/linux/utils/boot/syslinux/4.xx/syslinux-${PV}.tar.bz2"
|
|
|
|
SRC_URI[md5sum] = "9ff6e1b94efab931fb4717b600d88779"
|
|
SRC_URI[sha256sum] = "1240a4e4219b518bdaef78931b6e901befeff35e6894ac6db785115848a7a05a"
|
|
|
|
COMPATIBLE_HOST = '(x86_64|i.86).*-(linux|freebsd.*)'
|
|
|
|
EXTRA_OEMAKE = " \
|
|
BINDIR=${bindir} SBINDIR=${sbindir} LIBDIR=${libdir} \
|
|
DATADIR=${datadir} MANDIR=${mandir} INCDIR=${includedir} \
|
|
"
|
|
# syslinux uses $LD for linking, strip `-Wl,' so it can work
|
|
export LDFLAGS = "`echo $LDFLAGS | sed 's/-Wl,//g'`"
|
|
|
|
do_configure() {
|
|
# drop win32 targets or build fails
|
|
sed -e 's,win32/\S*,,g' -i Makefile
|
|
|
|
# clean installer executables included in source tarball
|
|
oe_runmake clean
|
|
}
|
|
|
|
do_compile() {
|
|
# Rebuild only the installer; keep precompiled bootloaders
|
|
# as per author's request (doc/distrib.txt)
|
|
oe_runmake CC="${CC} ${CFLAGS}" LDFLAGS="${LDFLAGS}" installer
|
|
}
|
|
|
|
do_install() {
|
|
oe_runmake install INSTALLROOT="${D}"
|
|
|
|
install -d ${D}${datadir}/syslinux/
|
|
install -m 644 ${S}/core/ldlinux.sys ${D}${datadir}/syslinux/
|
|
install -m 644 ${S}/core/ldlinux.bss ${D}${datadir}/syslinux/
|
|
}
|
|
|
|
PACKAGES += "${PN}-extlinux ${PN}-mbr ${PN}-chain ${PN}-pxelinux ${PN}-isolinux ${PN}-misc"
|
|
|
|
RDEPENDS_${PN} += "mtools"
|
|
|
|
FILES_${PN} = "${bindir}/syslinux"
|
|
FILES_${PN}-extlinux = "${sbindir}/extlinux"
|
|
FILES_${PN}-mbr = "${datadir}/${BPN}/mbr.bin"
|
|
FILES_${PN}-chain = "${datadir}/${BPN}/chain.c32"
|
|
FILES_${PN}-isolinux = "${datadir}/${BPN}/isolinux.bin"
|
|
FILES_${PN}-pxelinux = "${datadir}/${BPN}/pxelinux.0"
|
|
FILES_${PN}-dev += "${datadir}/${BPN}/com32/lib*${SOLIBS} ${datadir}/${BPN}/com32/include ${datadir}/${BPN}/com32/com32.ld"
|
|
FILES_${PN}-staticdev += "${datadir}/${BPN}/com32/lib*.a ${libdir}/${BPN}/com32/lib*.a"
|
|
FILES_${PN}-misc = "${datadir}/${BPN}/* ${libdir}/${BPN}/* ${bindir}/*"
|
|
|
|
BBCLASSEXTEND = "native"
|