The gettext handling of USE_NLS has become a bit tricky to understand, or alter from the SDK context. This patch introduces a SDKUSE_NLS which can be set to configure a given SDK/ADT to use NLS or not. This is independent of the target system NLS usage. The code in gettext.bbclass is therefore simplified and the classes themselves now set USE_NLS to appropriate values. No NLS is used for native, cross and crosssdk since it is never used there and would just increase build time. (From OE-Core rev: fe634d47449899f7424adb77ff5bc7ddf8a07a47) Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
80 lines
2.4 KiB
Text
80 lines
2.4 KiB
Text
inherit relocatable
|
|
|
|
# Cross packages are built indirectly via dependency,
|
|
# no need for them to be a direct target of 'world'
|
|
EXCLUDE_FROM_WORLD = "1"
|
|
|
|
CLASSOVERRIDE = "class-cross"
|
|
PACKAGES = ""
|
|
PACKAGES_DYNAMIC = ""
|
|
PACKAGES_DYNAMIC_class-native = ""
|
|
|
|
HOST_ARCH = "${BUILD_ARCH}"
|
|
HOST_VENDOR = "${BUILD_VENDOR}"
|
|
HOST_OS = "${BUILD_OS}"
|
|
HOST_PREFIX = "${BUILD_PREFIX}"
|
|
HOST_CC_ARCH = "${BUILD_CC_ARCH}"
|
|
HOST_LD_ARCH = "${BUILD_LD_ARCH}"
|
|
HOST_AS_ARCH = "${BUILD_AS_ARCH}"
|
|
|
|
STAGING_DIR_HOST = "${STAGING_DIR}/${HOST_ARCH}${HOST_VENDOR}-${HOST_OS}"
|
|
|
|
export PKG_CONFIG_DIR = "${STAGING_DIR}/${TUNE_PKGARCH}${TARGET_VENDOR}-${TARGET_OS}${libdir}/pkgconfig"
|
|
export PKG_CONFIG_SYSROOT_DIR = "${STAGING_DIR}/${TUNE_PKGARCH}${TARGET_VENDOR}-${TARGET_OS}"
|
|
|
|
CPPFLAGS = "${BUILD_CPPFLAGS}"
|
|
CFLAGS = "${BUILD_CFLAGS}"
|
|
CXXFLAGS = "${BUILD_CFLAGS}"
|
|
LDFLAGS = "${BUILD_LDFLAGS}"
|
|
LDFLAGS_build-darwin = "-L${STAGING_LIBDIR_NATIVE}"
|
|
|
|
TOOLCHAIN_OPTIONS = ""
|
|
|
|
DEPENDS_GETTEXT = "gettext-native"
|
|
|
|
# Path mangling needed by the cross packaging
|
|
# Note that we use := here to ensure that libdir and includedir are
|
|
# target paths.
|
|
target_base_prefix := "${base_prefix}"
|
|
target_prefix := "${prefix}"
|
|
target_exec_prefix := "${exec_prefix}"
|
|
target_base_libdir = "${target_base_prefix}/${baselib}"
|
|
target_libdir = "${target_exec_prefix}/${baselib}"
|
|
target_includedir := "${includedir}"
|
|
|
|
# Overrides for paths
|
|
CROSS_TARGET_SYS_DIR = "${MULTIMACH_TARGET_SYS}"
|
|
prefix = "${STAGING_DIR_NATIVE}${prefix_native}"
|
|
base_prefix = "${STAGING_DIR_NATIVE}"
|
|
exec_prefix = "${STAGING_DIR_NATIVE}${prefix_native}"
|
|
bindir = "${exec_prefix}/bin/${CROSS_TARGET_SYS_DIR}"
|
|
sbindir = "${bindir}"
|
|
base_bindir = "${bindir}"
|
|
base_sbindir = "${bindir}"
|
|
libdir = "${exec_prefix}/lib/${CROSS_TARGET_SYS_DIR}"
|
|
libexecdir = "${exec_prefix}/libexec/${CROSS_TARGET_SYS_DIR}"
|
|
|
|
do_populate_sysroot[sstate-inputdirs] = "${SYSROOT_DESTDIR}/${STAGING_DIR_NATIVE}/"
|
|
do_populate_sysroot[stamp-extra-info] = ""
|
|
|
|
python cross_virtclass_handler () {
|
|
classextend = e.data.getVar('BBCLASSEXTEND', True) or ""
|
|
if "cross" not in classextend:
|
|
return
|
|
|
|
pn = e.data.getVar("PN", True)
|
|
if not pn.endswith("-cross"):
|
|
return
|
|
|
|
bb.data.setVar("OVERRIDES", e.data.getVar("OVERRIDES", False) + ":virtclass-cross", e.data)
|
|
}
|
|
|
|
addhandler cross_virtclass_handler
|
|
cross_virtclass_handler[eventmask] = "bb.event.RecipePreFinalise"
|
|
|
|
do_install () {
|
|
oe_runmake 'DESTDIR=${D}' install
|
|
}
|
|
|
|
USE_NLS = "no"
|