* Sort the list so it's at least in some form of logical order. I looked at sorting by dependencies, but that's a topological sort, and given no such function is shipped as part of the python standard libraries it would seem excessive to pull one in just for this. In any case, I'm not sure that for the data we have this would lead to any particularly pleasing result. * Show the doc values as defined in documentation.conf (where present) as a description Addresses [YOCTO #4856]. (From OE-Core rev: 36828f8a0db83b5222a8589984e4a02aeb00eada) Signed-off-by: Paul Eggleton <paul.eggleton@linux.intel.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
70 lines
1.8 KiB
Text
70 lines
1.8 KiB
Text
addtask listtasks
|
|
do_listtasks[nostamp] = "1"
|
|
python do_listtasks() {
|
|
taskdescs = {}
|
|
maxlen = 0
|
|
for e in d.keys():
|
|
if d.getVarFlag(e, 'task'):
|
|
maxlen = max(maxlen, len(e))
|
|
if e.endswith('_setscene'):
|
|
desc = "%s (setscene version)" % (d.getVarFlag(e[:-9], 'doc') or '')
|
|
else:
|
|
desc = d.getVarFlag(e, 'doc') or ''
|
|
taskdescs[e] = desc
|
|
|
|
tasks = sorted(taskdescs.keys())
|
|
for taskname in tasks:
|
|
bb.plain("%s %s" % (taskname.ljust(maxlen), taskdescs[taskname]))
|
|
}
|
|
|
|
CLEANFUNCS ?= ""
|
|
|
|
T_task-clean = "${LOG_DIR}/cleanlogs/${PN}"
|
|
addtask clean
|
|
do_clean[nostamp] = "1"
|
|
python do_clean() {
|
|
"""clear the build and temp directories"""
|
|
dir = d.expand("${WORKDIR}")
|
|
bb.note("Removing " + dir)
|
|
oe.path.remove(dir)
|
|
|
|
dir = "%s.*" % bb.data.expand(d.getVar('STAMP'), d)
|
|
bb.note("Removing " + dir)
|
|
oe.path.remove(dir)
|
|
|
|
for f in (d.getVar('CLEANFUNCS', True) or '').split():
|
|
bb.build.exec_func(f, d)
|
|
}
|
|
|
|
addtask checkuri
|
|
do_checkuri[nostamp] = "1"
|
|
python do_checkuri() {
|
|
src_uri = (d.getVar('SRC_URI', True) or "").split()
|
|
if len(src_uri) == 0:
|
|
return
|
|
|
|
localdata = bb.data.createCopy(d)
|
|
bb.data.update_data(localdata)
|
|
|
|
try:
|
|
fetcher = bb.fetch2.Fetch(src_uri, localdata)
|
|
fetcher.checkstatus()
|
|
except bb.fetch2.BBFetchException, e:
|
|
raise bb.build.FuncFailed(e)
|
|
}
|
|
|
|
addtask checkuriall after do_checkuri
|
|
do_checkuriall[recrdeptask] = "do_checkuriall do_checkuri"
|
|
do_checkuriall[recideptask] = "do_${BB_DEFAULT_TASK}"
|
|
do_checkuriall[nostamp] = "1"
|
|
do_checkuriall() {
|
|
:
|
|
}
|
|
|
|
addtask fetchall after do_fetch
|
|
do_fetchall[recrdeptask] = "do_fetchall do_fetch"
|
|
do_fetchall[recideptask] = "do_${BB_DEFAULT_TASK}"
|
|
do_fetchall() {
|
|
:
|
|
}
|