Configuring gcc with --enable-target-optspace (which causes gcc to append "-g -Os" to the default CFLAGS_FOR_TARGET and so force libgcc etc target libraries to always be optimised for size) dates back to the very first commit in oe-core git in 2005 (for gcc 3.4.3). Configuring gcc with --enable-target-optspace is not done widely elsewhere (it's not used for Ubuntu or Fedora host gcc, the Linaro binary toolchain or in Buildroot since early 2015). Sometime around gcc 4.5.x it caused problems for powerpc and so was disabled for that architecture: https://gcc.gnu.org/bugzilla/show_bug.cgi?id=43810 This patch removes --enable-target-optspace completely (ie powerpc is no longer a special case) and allows optimisation of libgcc etc to be controlled directly by the flags present in TARGET_CFLAGS. (From OE-Core rev: 686b266506a1a56fb68ab0f00d658787dd7fe4ce) Signed-off-by: Andre McCurdy <armccurdy@gmail.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
123 lines
4.3 KiB
PHP
123 lines
4.3 KiB
PHP
require gcc-multilib-config.inc
|
|
require gcc-shared-source.inc
|
|
#
|
|
# Build the list of lanaguages to build.
|
|
#
|
|
# These can be overridden by the version specific .inc file.
|
|
|
|
# Java (gcj doesn't work on all architectures)
|
|
JAVA ?= ",java"
|
|
JAVA_arm ?= ""
|
|
JAVA_armeb ?= ""
|
|
JAVA_mipsel ?= ""
|
|
JAVA_sh3 ?= ""
|
|
# gcc 3.x expects 'f77', 4.0 expects 'f95', 4.1 and 4.2 expect 'fortran'
|
|
FORTRAN ?= ",f77"
|
|
LANGUAGES ?= "c,c++${FORTRAN}${JAVA}"
|
|
|
|
EXTRA_OECONF_BASE ?= ""
|
|
EXTRA_OECONF_PATHS ?= ""
|
|
EXTRA_OECONF_INITIAL ?= ""
|
|
|
|
GCCMULTILIB ?= "--disable-multilib"
|
|
GCCTHREADS ?= "posix"
|
|
|
|
EXTRA_OECONF = "\
|
|
${@['--enable-clocale=generic', ''][d.getVar('USE_NLS', True) != 'no']} \
|
|
--with-gnu-ld \
|
|
--enable-shared \
|
|
--enable-languages=${LANGUAGES} \
|
|
--enable-threads=${GCCTHREADS} \
|
|
${GCCMULTILIB} \
|
|
--enable-c99 \
|
|
--enable-long-long \
|
|
--enable-symvers=gnu \
|
|
--enable-libstdcxx-pch \
|
|
--program-prefix=${TARGET_PREFIX} \
|
|
--without-local-prefix \
|
|
${EXTRA_OECONF_BASE} \
|
|
${EXTRA_OECONF_GCC_FLOAT} \
|
|
${EXTRA_OECONF_PATHS} \
|
|
${@get_gcc_mips_plt_setting(bb, d)} \
|
|
${@get_gcc_ppc_plt_settings(bb, d)} \
|
|
${@get_long_double_setting(bb, d)} \
|
|
${@get_gcc_multiarch_setting(bb, d)} \
|
|
"
|
|
|
|
export gcc_cv_collect2_libs = 'none required'
|
|
# We need to set gcc_cv_collect2_libs else there is cross-compilation badness
|
|
# in the config.log files (which might not get generated until do_compile
|
|
# hence being missed by the insane do_configure check).
|
|
|
|
# Build uclibc compilers without cxa_atexit support
|
|
EXTRA_OECONF_append_linux = " --enable-__cxa_atexit"
|
|
EXTRA_OECONF_append_libc-uclibc = " --enable-__cxa_atexit"
|
|
|
|
EXTRA_OECONF_append_mips64 = " --with-abi=64 --with-arch-64=mips64 --with-tune-64=mips64"
|
|
EXTRA_OECONF_append_mips64el = " --with-abi=64 --with-arch-64=mips64 --with-tune-64=mips64"
|
|
EXTRA_OECONF_append_mips64n32 = " --with-abi=64 --with-arch-64=mips64 --with-tune-64=mips64"
|
|
EXTRA_OECONF_append_mips64eln32 = " --with-abi=64 --with-arch-64=mips64 --with-tune-64=mips64"
|
|
|
|
# ARMv6+ adds atomic instructions that affect the ABI in libraries built
|
|
# with TUNE_CCARGS in gcc-runtime. Make the compiler default to a
|
|
# compatible architecture. armv6 and armv7a cover the minimum tune
|
|
# features used in OE.
|
|
EXTRA_OECONF_append_armv6 = " --with-arch=armv6"
|
|
EXTRA_OECONF_append_armv7a = " --with-arch=armv7-a"
|
|
EXTRA_OECONF_append_armv7ve = " --with-arch=armv7-a"
|
|
|
|
EXTRA_OECONF_GCC_FLOAT ??= ""
|
|
CPPFLAGS = ""
|
|
|
|
SYSTEMHEADERS = "${target_includedir}"
|
|
SYSTEMLIBS = "${target_base_libdir}/"
|
|
SYSTEMLIBS1 = "${target_libdir}/"
|
|
|
|
do_configure_prepend () {
|
|
# teach gcc to find correct target includedir when checking libc ssp support
|
|
mkdir -p ${B}/gcc
|
|
echo "NATIVE_SYSTEM_HEADER_DIR = ${SYSTEMHEADERS}" > ${B}/gcc/t-oe
|
|
cat ${S}/gcc/defaults.h | grep -v "\#endif.*GCC_DEFAULTS_H" > ${B}/gcc/defaults.h.new
|
|
cat >>${B}/gcc/defaults.h.new <<_EOF
|
|
#define NATIVE_SYSTEM_HEADER_DIR "${SYSTEMHEADERS}"
|
|
#define STANDARD_STARTFILE_PREFIX_1 "${SYSTEMLIBS}"
|
|
#define STANDARD_STARTFILE_PREFIX_2 "${SYSTEMLIBS1}"
|
|
#define SYSTEMLIBS_DIR "${SYSTEMLIBS}"
|
|
#endif /* ! GCC_DEFAULTS_H */
|
|
_EOF
|
|
mv ${B}/gcc/defaults.h.new ${B}/gcc/defaults.h
|
|
}
|
|
|
|
do_configure () {
|
|
# Setup these vars for cross building only
|
|
# ... because foo_FOR_TARGET apparently gets misinterpreted inside the
|
|
# gcc build stuff when the build is producing a cross compiler - i.e.
|
|
# when the 'current' target is the 'host' system, and the host is not
|
|
# the target (because the build is actually making a cross compiler!)
|
|
if [ "${BUILD_SYS}" != "${HOST_SYS}" ]; then
|
|
export CC_FOR_TARGET="${CC}"
|
|
export GCC_FOR_TARGET="${CC}"
|
|
export CXX_FOR_TARGET="${CXX}"
|
|
export AS_FOR_TARGET="${HOST_PREFIX}as"
|
|
export LD_FOR_TARGET="${HOST_PREFIX}ld"
|
|
export NM_FOR_TARGET="${HOST_PREFIX}nm"
|
|
export AR_FOR_TARGET="${HOST_PREFIX}ar"
|
|
export GFORTRAN_FOR_TARGET="gfortran"
|
|
export RANLIB_FOR_TARGET="${HOST_PREFIX}ranlib"
|
|
fi
|
|
export CC_FOR_BUILD="${BUILD_CC}"
|
|
export CXX_FOR_BUILD="${BUILD_CXX}"
|
|
export CFLAGS_FOR_BUILD="${BUILD_CFLAGS}"
|
|
export CPPFLAGS_FOR_BUILD="${BUILD_CPPFLAGS}"
|
|
export CXXFLAGS_FOR_BUILD="${BUILD_CXXFLAGS}"
|
|
export LDFLAGS_FOR_BUILD="${BUILD_LDFLAGS}"
|
|
export CFLAGS_FOR_TARGET="${TARGET_CFLAGS}"
|
|
export CPPFLAGS_FOR_TARGET="${TARGET_CPPFLAGS}"
|
|
export CXXFLAGS_FOR_TARGET="${TARGET_CXXFLAGS}"
|
|
export LDFLAGS_FOR_TARGET="${TARGET_LDFLAGS}"
|
|
|
|
|
|
oe_runconf
|
|
}
|
|
|