cd843b3207
Use the "libdir" and "sysconfdir" variables rather than hard-coding "/usr/lib" and "/etc". (From OE-Core rev: 1ae73bb41436bf7e97d83052fbe1541074b4a4ac) Signed-off-by: Drew Moseley <drew_moseley@mentor.com> Signed-off-by: Saul Wold <sgw@linux.intel.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
43 lines
1.5 KiB
PHP
43 lines
1.5 KiB
PHP
SUMMARY = "OpenMAX IL plugins for GStreamer"
|
|
SECTION = "multimedia"
|
|
LICENSE = "LGPLv2.1"
|
|
LICENSE_FLAGS = "commercial"
|
|
HOMEPAGE = "http://www.gstreamer.net/"
|
|
DEPENDS = "gstreamer1.0 gstreamer1.0-plugins-base"
|
|
RDEPENDS_${PN} = "libomxil"
|
|
|
|
inherit autotools pkgconfig gettext
|
|
|
|
acpaths = "-I ${S}/common/m4 -I ${S}/m4"
|
|
|
|
PR = "r1"
|
|
|
|
GSTREAMER_1_0_OMX_TARGET ?= "bellagio"
|
|
GSTREAMER_1_0_OMX_CORE_NAME ?= "${libdir}/libomxil-bellagio.so.0"
|
|
|
|
EXTRA_OECONF += "--disable-valgrind --with-omx-target=${GSTREAMER_1_0_OMX_TARGET}"
|
|
|
|
python __anonymous () {
|
|
omx_target = d.getVar("GSTREAMER_1_0_OMX_TARGET", True)
|
|
if omx_target in ['generic', 'bellagio']:
|
|
srcdir = d.getVar("S", True)
|
|
# Bellagio headers are incomplete (they are missing the OMX_VERSION_MAJOR,#
|
|
# OMX_VERSION_MINOR, OMX_VERSION_REVISION, and OMX_VERSION_STEP macros);
|
|
# appending a directory path to gst-omx' internal OpenMAX IL headers fixes this
|
|
d.appendVar("CFLAGS", " -I%s/omx/openmax" % srcdir)
|
|
elif omx_target == "rpi":
|
|
# Dedicated Raspberry Pi OpenMAX IL support makes this package machine specific
|
|
d.setVar("PACKAGE_ARCH", d.getVar("MACHINE_ARCH", True))
|
|
}
|
|
|
|
set_omx_core_name() {
|
|
sed -i -e "s;^core-name=.*;core-name=${GSTREAMER_1_0_OMX_CORE_NAME};" "${D}${sysconfdir}/xdg/gstomx.conf"
|
|
}
|
|
do_install[postfuncs] += " set_omx_core_name "
|
|
|
|
FILES_${PN} += "${libdir}/gstreamer-1.0/*.so"
|
|
FILES_${PN}-dbg += "${libdir}/gstreamer-1.0/.debug"
|
|
FILES_${PN}-dev += "${libdir}/gstreamer-1.0/*.la"
|
|
FILES_${PN}-staticdev += "${libdir}/gstreamer-1.0/*.a"
|
|
|