b8b4a92625
This allows pango to be installed in an image with read-only-rootfs. (From OE-Core rev: 62381fd3a135318794f14dc3740b04facd32446e) Signed-off-by: Phil Blundell <philb@gnu.org> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
55 lines
1.9 KiB
PHP
55 lines
1.9 KiB
PHP
SUMMARY = "Framework for layout and rendering of internationalized text"
|
|
DESCRIPTION = "Pango is a library for laying out and rendering of text, \
|
|
with an emphasis on internationalization. Pango can be used anywhere \
|
|
that text layout is needed, though most of the work on Pango so far has \
|
|
been done in the context of the GTK+ widget toolkit. Pango forms the \
|
|
core of text and font handling for GTK+-2.x."
|
|
HOMEPAGE = "http://www.pango.org/"
|
|
BUGTRACKER = "http://bugzilla.gnome.org"
|
|
SECTION = "libs"
|
|
LICENSE = "LGPL"
|
|
|
|
X11DEPENDS = "virtual/libx11 libxft"
|
|
DEPENDS = "glib-2.0 fontconfig freetype zlib virtual/libiconv gtk-doc-native cairo qemu-native ${@base_contains('DISTRO_FEATURES', 'x11', '${X11DEPENDS}', '', d)}"
|
|
|
|
PACKAGES_DYNAMIC = "pango-module-*"
|
|
|
|
RRECOMMENDS_${PN} = "${@base_contains('DISTRO_FEATURES', 'x11', 'pango-module-basic-x', '', d)} pango-module-basic-fc"
|
|
|
|
inherit gnome qemu
|
|
|
|
EXTRA_AUTORECONF = ""
|
|
|
|
# seems to go wrong with default cflags
|
|
FULL_OPTIMIZATION_arm = "-O2"
|
|
|
|
EXTRA_OECONF = "--disable-glibtest \
|
|
--enable-explicit-deps=no \
|
|
--disable-debug \
|
|
${@base_contains('DISTRO_FEATURES', 'x11', '--with-x', '--without-x', d)}"
|
|
|
|
LEAD_SONAME = "libpango-1.0*"
|
|
LIBV = "1.6.0"
|
|
|
|
postinst_prologue() {
|
|
if [ "x$D" != "x" ]; then
|
|
if [ ! -f "$D${sysconfdir}/pango/pango.modules" ]; then
|
|
mkdir -p $D${sysconfdir}/pango
|
|
PSEUDO_RELOADED=YES ${@qemu_target_binary(d)} -L $D $D${bindir}/pango-querymodules > "$D${sysconfdir}/pango/pango.modules"
|
|
fi
|
|
exit 0
|
|
fi
|
|
}
|
|
|
|
python populate_packages_prepend () {
|
|
prologue = bb.data.getVar("postinst_prologue", d, 1)
|
|
|
|
modules_root = bb.data.expand('${libdir}/pango/${LIBV}/modules', d)
|
|
|
|
do_split_packages(d, modules_root, '^pango-(.*)\.so$', 'pango-module-%s', 'Pango module %s', prologue + 'pango-querymodules > /etc/pango/pango.modules')
|
|
}
|
|
|
|
FILES_${PN} = "/etc ${bindir}/* ${libdir}/libpango*${SOLIBS}"
|
|
FILES_${PN}-dbg += "${libdir}/pango/${LIBV}/modules/.debug"
|
|
FILES_${PN}-dev += "${libdir}/pango/${LIBV}/modules/*.la"
|