bb files: remove invalid config.sub/config.guess files (autotools will generate the correct files) allocate-larger-memory.patch: not needed anymore fix-gcc-4.6-null-not-defined.patch: added - include header that defines NULL includes-fix.patch: not needed anymore localefixes.patch: removed - not necessary anymore (no compiling errors) makerace.patch: adapted to the new version no-ko-translation.patch: adapted to the new version no-nls-dpkg.patch: added - fix build without nls noconfigure.patch: adapted to the new version nodoc.patch: adapted to the new version (apply patch on all cases because the doc generation needs docbook-xsl) remove-redeclaration.patch: not needed anymore truncate-filename.patch: moved use-host.patch: adapted to the new version no-curl.patch: adapted to the new version disable-configure-in-makefile.patch: added - do not run configure at do_compile (From OE-Core rev: 97403b14765331c8c48bb570c6b98f2809214a9a) Signed-off-by: Constantin Musca <constantinx.musca@intel.com> Signed-off-by: Saul Wold <sgw@linux.intel.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
68 lines
2.3 KiB
PHP
68 lines
2.3 KiB
PHP
require apt.inc
|
|
inherit native
|
|
|
|
DEPENDS += "dpkg-native gettext-native"
|
|
PACKAGES = ""
|
|
USE_NLS = "yes"
|
|
|
|
SRC_URI += "file://db_linking_hack.patch"
|
|
|
|
python do_install () {
|
|
bb.build.exec_func('do_install_base', d)
|
|
bb.build.exec_func('do_install_config', d)
|
|
}
|
|
|
|
python do_install_config () {
|
|
indir = os.path.dirname(d.getVar('FILE',1))
|
|
infile = file(oe.path.join(indir, 'files', 'apt.conf'), 'r')
|
|
data = infile.read()
|
|
infile.close()
|
|
|
|
data = d.expand(data)
|
|
|
|
outdir = oe.path.join(d.getVar('D', True), d.getVar('sysconfdir', True), 'apt')
|
|
if not os.path.exists(outdir):
|
|
os.makedirs(outdir)
|
|
|
|
outpath = oe.path.join(outdir, 'apt.conf.sample')
|
|
if not os.path.exists(outpath):
|
|
outfile = file(outpath, 'w')
|
|
outfile.write(data)
|
|
outfile.close()
|
|
}
|
|
|
|
do_install_base () {
|
|
install -d ${D}${bindir}
|
|
install -m 0755 bin/apt-cdrom ${D}${bindir}/
|
|
install -m 0755 bin/apt-get ${D}${bindir}/
|
|
install -m 0755 bin/apt-config ${D}${bindir}/
|
|
install -m 0755 bin/apt-cache ${D}${bindir}/
|
|
install -m 0755 bin/apt-sortpkgs ${D}${bindir}/
|
|
install -m 0755 bin/apt-extracttemplates ${D}${bindir}/
|
|
|
|
eval `cat environment.mak | grep ^GLIBC_VER | sed -e's, = ,=,'`
|
|
eval `cat environment.mak | grep ^LIBSTDCPP_VER | sed -e's, = ,=,'`
|
|
oe_libinstall -so -C bin libapt-pkg$GLIBC_VER$LIBSTDCPP_VER ${D}${libdir}/
|
|
ln -sf libapt-pkg$GLIBC_VER$LIBSTDCPP_VER.so ${D}${libdir}/libapt-pkg.so
|
|
oe_libinstall -so -C bin libapt-inst$GLIBC_VER$LIBSTDCPP_VER ${D}${libdir}/
|
|
ln -sf libapt-inst$GLIBC_VER$LIBSTDCPP_VER.so ${D}${libdir}/libapt-inst.so
|
|
|
|
install -d ${D}${libdir}/apt/methods
|
|
install -m 0755 bin/methods/* ${D}${libdir}/apt/methods/
|
|
|
|
install -d ${D}${libdir}/dpkg/methods/apt
|
|
install -m 0644 dselect/desc.apt ${D}${libdir}/dpkg/methods/apt/
|
|
install -m 0644 dselect/names ${D}${libdir}/dpkg/methods/apt/
|
|
install -m 0755 dselect/install ${D}${libdir}/dpkg/methods/apt/
|
|
install -m 0755 dselect/setup ${D}${libdir}/dpkg/methods/apt/
|
|
install -m 0755 dselect/update ${D}${libdir}/dpkg/methods/apt/
|
|
|
|
install -d ${D}${sysconfdir}/apt
|
|
install -d ${D}${sysconfdir}/apt/apt.conf.d
|
|
install -d ${D}${sysconfdir}/apt/preferences.d
|
|
install -d ${D}${localstatedir}/lib/apt/lists/partial
|
|
install -d ${D}${localstatedir}/cache/apt/archives/partial
|
|
|
|
install -d ${D}${localstatedir}/log/apt/
|
|
}
|