55 lines
1.6 KiB
BlitzBasic
55 lines
1.6 KiB
BlitzBasic
SUMMARY = "Freetype font rendering library"
|
|
DESCRIPTION = "FreeType is a software font engine that is designed to be small, efficient, \
|
|
highly customizable, and portable while capable of producing high-quality output (glyph \
|
|
images). It can be used in graphics libraries, display servers, font conversion tools, text \
|
|
image generation tools, and many other products as well."
|
|
HOMEPAGE = "http://www.freetype.org/"
|
|
BUGTRACKER = "https://savannah.nongnu.org/bugs/?group=freetype"
|
|
|
|
LICENSE = "FreeType | GPLv2+"
|
|
LIC_FILES_CHKSUM = "file://docs/LICENSE.TXT;md5=c017ff17fc6f0794adf93db5559ccd56 \
|
|
file://docs/FTL.TXT;md5=d479e83797f699fe873b38dadd0fcd4c \
|
|
file://docs/GPLv2.TXT;md5=8ef380476f642c20ebf40fecb0add2ec"
|
|
|
|
SECTION = "libs"
|
|
|
|
SRC_URI = "${SOURCEFORGE_MIRROR}/freetype/freetype-${PV}.tar.bz2 \
|
|
"
|
|
|
|
SRC_URI[md5sum] = "c72e9010b1d986d556fc0b2b5fcbf31a"
|
|
SRC_URI[sha256sum] = "57bce5b37989577aa8b4a588426839f6bf39bcc3869748cb18f6827df251f4e5"
|
|
|
|
S = "${WORKDIR}/freetype-${PV}"
|
|
|
|
inherit autotools pkgconfig binconfig
|
|
|
|
LIBTOOL = "${S}/builds/unix/${HOST_SYS}-libtool"
|
|
EXTRA_OEMAKE = "'LIBTOOL=${LIBTOOL}'"
|
|
EXTRA_OEMAKE_class-native = ""
|
|
EXTRA_OECONF = "--without-zlib --without-bzip2 CC_BUILD='${BUILD_CC}'"
|
|
|
|
PACKAGECONFIG ??= ""
|
|
PACKAGECONFIG[pixmap] = "--with-png,--without-png,libpng"
|
|
|
|
do_configure() {
|
|
cd builds/unix
|
|
libtoolize --force --copy
|
|
aclocal -I .
|
|
gnu-configize --force
|
|
autoconf
|
|
cd ${S}
|
|
oe_runconf
|
|
}
|
|
|
|
do_configure_class-native() {
|
|
(cd builds/unix && gnu-configize) || die "failure running gnu-configize"
|
|
oe_runconf
|
|
}
|
|
|
|
do_compile_prepend() {
|
|
${BUILD_CC} -o objs/apinames src/tools/apinames.c
|
|
}
|
|
|
|
BBCLASSEXTEND = "native"
|
|
|