From 812eceaea35c9f0ca6d85dbc6147a74a9834ab7a Mon Sep 17 00:00:00 2001
From: Holger Hans Peter Freyther <holger@moiji-mobile.com>
Date: Fri, 21 Nov 2014 23:42:42 +0100
Subject: [PATCH] openvpn: Add OpenVPN 2.3.4 recipe from upstream OpenEmbedded

We should use a more recent version of the OpenVPN client. Import
it from the meta-networking layer like we did before. The sysvinit
script has just minor whitespace differences and wasn't imported.

We need to test opkg upgrades of OpenVPN through the VPN. We don't
want to kill the tunnel on such upgrade.
---
 recipes-extra/openvpn/openvpn_2.3.4.bb | 37 ++++++++++++++++++++++++++
 1 file changed, 37 insertions(+)
 create mode 100644 recipes-extra/openvpn/openvpn_2.3.4.bb

diff --git a/recipes-extra/openvpn/openvpn_2.3.4.bb b/recipes-extra/openvpn/openvpn_2.3.4.bb
new file mode 100644
index 0000000..3e52c81
--- /dev/null
+++ b/recipes-extra/openvpn/openvpn_2.3.4.bb
@@ -0,0 +1,37 @@
+SUMMARY = "A full-featured SSL VPN solution via tun device."
+HOMEPAGE = "http://openvpn.sourceforge.net"
+SECTION = "console/network"
+LICENSE = "GPLv2"
+LIC_FILES_CHKSUM = "file://COPYING;md5=5aac200199fde47501876cba7263cb0c"
+DEPENDS = "lzo openssl iproute2 ${@base_contains('DISTRO_FEATURES', 'pam', 'libpam', '', d)}"
+
+inherit autotools
+
+SRC_URI = "http://swupdate.openvpn.org/community/releases/openvpn-${PV}.tar.gz \
+           file://openvpn"
+
+SRC_URI[md5sum] = "04d47237907faabe9d046970ffe44b2e"
+SRC_URI[sha256sum] = "af506d5f48568fa8d2f2435cb3fad35f9a9a8f263999ea6df3ba296960cec85a"
+
+CFLAGS += "-fno-inline"
+
+# I want openvpn to be able to read password from file (hrw)
+EXTRA_OECONF += "--enable-password-save --enable-iproute2"
+EXTRA_OECONF += "${@base_contains('DISTRO_FEATURES', 'pam', '', '--disable-plugin-auth-pam', d)}"
+
+# Explicitly specify IPROUTE to bypass the configure-time check for /sbin/ip on the host.
+EXTRA_OECONF += "IPROUTE=/sbin/ip"
+
+do_install_append() {
+    install -d ${D}/${sysconfdir}/init.d
+    install -d ${D}/${sysconfdir}/openvpn
+    install -m 755 ${WORKDIR}/openvpn ${D}/${sysconfdir}/init.d
+}
+
+RRECOMMENDS_${PN} = "kernel-module-tun"
+
+FILES_${PN}-dbg += "${libdir}/openvpn/plugins/.debug"
+
+
+# We need to test opkg upgrade of OpenVPN through the OpenVPN first
+DEFAULT_PREFERENCE = "-1"