inherit kernel
require linux-sysmocom.inc

LINUX_VERSION ?= "3.2.48"
LINUX_VERSION_EXTENSION ?= "-sysmocom-${LINUX_KERNEL_TYPE}"

# Overrides for the sysmocom bts v1
BTS_FIRMWARE_NAME_sysmobts-v1 = "sysmobts-v1"

# Overrides for the sysmocom bts v2
BTS_FIRMWARE_NAME_sysmobts-v2 = "sysmobts-v2"
BTS_FIRMWARE_NAME_sysmobts-2050 = "sysmobts-v2"

SRCREV = "bcc4fa827be7f59486ff305d664b42a142025f9b"

# odu handling.
SRCREV_sysmocom-odu = "aadf22be50ac2abb2a9437b9ad3bba4ccdca540b"
LINUX_VERSION_sysmocom-odu = "3.2.63"

PR = "r37"
PV = "${LINUX_VERSION}+git${SRCPV}"

SRC_URI = "git://git.sysmocom.de/sysmo-bts/linux.git;protocol=git;branch=v3.2 \
	   file://mISDN_loop.patch;patch=1 \
	   file://defconfig"
S = "${WORKDIR}/git"

COMPATIBLE_MACHINE = "(sysmobts-v1|sysmobts-v2|sysmobts-2050|sysmocom-odu)"
EXTRA_OEMAKE += "KALLSYMS_EXTRA_PASS=1"

# we do not want to have the kernel image inside the kernel
FILES_kernel-image_sysmobts-v1 = ""

require linux-tools.inc

do_configure() {
	install -m 0644 ${WORKDIR}/defconfig ${S}/.config
	oe_runmake oldconfig
}

# autoload defaults (alphabetically sorted)
module_autoload_davinci_mmc = "davinci_mmc"
module_autoload_davinci_wdt = "davinci_wdt"
module_autoload_dspdl_dm644x = "dspdl_dm644x"
module_autoload_fpgadl_par = "fpgadl_par"
module_autoload_leds-gpio = "leds-gpio"
module_autoload_mmc_block = "mmc_block"
module_autoload_msgqueue = "msgqueue"
module_autoload_rtfifo = "rtfifo"

# module configs (alphabetically sorted)
module_conf_dspdl_dm644x = "options dspdl_dm644x fw_name=${BTS_FIRMWARE_NAME}.out debug=0"
module_conf_fpgadl_par = "options fpgadl_par fw_name=${BTS_FIRMWARE_NAME}.bit"
module_conf_msgqueue = "options msgqueue fw_name=${BTS_FIRMWARE_NAME}.out"
module_conf_rtfifo = "options rtfifo fw_name=${BTS_FIRMWARE_NAME}.out"

RDEPENDS_kernel-module-dspdl-dm644x += "sysmobts-firmware"
RDEPENDS_kernel-module-fpgadl-par += "sysmobts-firmware"
RDEPENDS_kernel-module-msgqueue += "sysmobts-firmware"
RDEPENDS_kernel-module-rtfifo += "sysmobts-firmware"

DEFAULT_PREFERENCE = "20"