DESCRIPTION = "sysmocom OsmoBTS"
LICENSE = "AGPLv3"
LIC_FILES_CHKSUM="file://COPYING;md5=73f1eb20517c55bf9493b7dd6e480788"

SRC_URI = "git://git.osmocom.org/osmo-bts.git;protocol=git;branch=sysmocom/0.3.0-next;name=osmobts;destsuffix=git \
           git://git.osmocom.org/openbsc;protocol=git;branch=master;name=openbsc;destsuffix=openbsc"
SRCREV_osmobts = "b469e7314860794aebd904ebc4a63f877c01c3fc"
SRCREV_openbsc = "6a399efb720dc05b9ac4ae2010199301cb0e4ef1"
PV = "0.3.0+git${SRCPV}"
PR = "r1.${META_TELEPHONY_OSMO_INC}"
S = "${WORKDIR}/git"

SRCREV_FORMAT = "openbsc-rosmobts"
DEPENDS = "libosmocore libosmo-abis femtobts-api"
RDEPENDS_${PN} += "coreutils"

EXTRA_OECONF += "--enable-sysmocom-bts"

inherit autotools update-rc.d

# Select the API version
inherit femtobts_api
CPPFLAGS += " ${BTS_HW_VERSION} "

do_configure_prepend() {
	ln -sf ../openbsc openbsc
}

do_compile_append_sysmobts-v2() {
	cd ${S}/contrib/sysmobts-calib/
	oe_runmake
}

do_install_append() {
	install -d ${D}${sysconfdir}/osmocom
	install -m 0660 ${S}/doc/examples/osmo-bts.cfg ${D}${sysconfdir}/osmocom
	install -m 0755 ${S}/contrib/respawn.sh ${D}${sysconfdir}/osmocom/
	install -m 0755 ${S}/contrib/respawn-only.sh ${D}${sysconfdir}/osmocom/
	install -m 0644 ${S}/contrib/screenrc-sysmobts ${D}${sysconfdir}/osmocom/
	install -d ${D}${sysconfdir}/init.d
	install -m 0755 ${S}/contrib/sysmobts.init ${D}${sysconfdir}/init.d/sysmobts

}

do_install_append_sysmobts-v2() {
	install -m 0755 ${S}/contrib/sysmobts-calib/sysmobts-calib ${D}${bindir}/
}

CONFFILES_${PN} = "${sysconfdir}/osmocom/osmo-bts.cfg"
INITSCRIPT_PACKAGES = "${PN}"
INITSCRIPT_NAME_${PN} = "sysmobts"
INITSCRIPT_PARAMS_${PN} = "defaults 30 30"

PACKAGES =+ "osmo-bts-remote sysmobts-calib sysmobts-util"

FILES_osmo-bts-remote = " ${bindir}/sysmobts-remote "
FILES_sysmobts-calib = " ${bindir}/sysmobts-calib "
FILES_sysmobts-util = " ${bindir}/sysmobts-util "